Vsebina

# Funkcije za besedilo

To poglavje vsebuje opise funkcij za besedilo.

Za dostop do tega ukaza ...

Vstavi – Funkcija – Kategorija Besedilo

## Raba dvojnih narekovajev v formulah

Če želite v formulo vključiti besedilni niz, ga postavite med dva dvojna narekovaja (") in Calc povzame znake v nizu brez interpretacije. Primer: formula ="Žive naj vsi narodi!" prikaže besedilni niz Žive naj vsi narodi! v celici brez obkrožajočih dvojnih narekovajev.

Kompleksnejša formula =CONCATENATE("Življenje je resnično enostavno, "; "vendar vztrajamo, da ga naredimo zapletenega "; "(Konfucij).") spoji tri posamezne nize v narekovajih, tako da vrne Življenje je resnično enostavno, vendar vztrajamo, da ga naredimo zapletenega (Konfucij).

Če želite v niz v formuli vstaviti dvojni narekovaj, sta na voljo dva načina:

1. Dvojni narekovaj lahko podate z ubežnimi znaki, tako da dodate dvojni narekovaj, Calc pa obravnava takšen ubežen narekovaj kot dobesedno vrednost. Primer: formula ="Ime mi je ""Janez Novak""." vrne niz Ime mi je "Janez Novak". Še en enostaven primer: formula =UNICODE(""""), ki vrne 34, desetiško vrednost znaka Unicode za narekovaj (U+0022) — tukaj prvi in četrti dvojni narekovaj nakazujeta začetek in konec niza, drugi dvojni narekovaj pa ubeži tretjega.

2. Uporabite lahko funkcijo CHAR ali funkcijo UNICHAR, da vstavite dvojni narekov. Primer: formula =UNICHAR(34) & "Varuh v rži" & UNICHAR(34) & " je sloviti roman J. D. Salingerja." izpiše niz "Varuh v rži" je sloviti roman J. D. Salingerja.

Upoštevajte, da lahko funkcija Samopopravki modula Calc dvojne narekovaje spremeni. Samopopravki ne smejo spreminjati dvojnih narekovajev v celicah, lahko pa spremenijo tiste, uporabljene v celicah brez formul, ki vsebujejo besedilo. Primer: če kopirate niz, ki ga obkroža druga tipografska vrsta dvojnih narekovajev, kot sta npr. levi dvojni narekovaj (U+201C) in desni dvojni narekovaj (U+201D), in ga nato prilepite v celico s formulo, lahko pride do napake. Odprite področje Dvojni narekovaji v pogovornem oknu Orodja — Možnosti samopopravkov — Posebnosti jezika, da določite znake, ki bodo samodejno popravili začetne in končne tipografske dvojne narekovaje. Prekličite potrditev možnosti Zamenjaj, da onemogočite to funkcijo.

## ARABIC

Vrne številsko vrednost, ki ustreza rimskemu številu, izraženem v besedilni obliki.

## ASC

Pretvori znake dveh bajtov (polne širine) v znake enojnega bajta (polovične širine) ASCII in znake katakana.

## JIS

Pretvori eno-bajtne znake ASCII ali katakana (polovične širine) v dvo-bajtne znake polne širine.

## REGEX

Najde zadetke s pomočjo regularnih izrazov in po potrebi zamenja besedilo.

## ROMAN

Arabska števila spremeni v rimska. Vrednost števila mora biti med 0 in 3999, pri načinu pa lahko uporabite cela števila med 0 in 4.

## VALUE

Pretvori zapis števila kot niza v numerično obliko. Če je podani niz veljaven datum, čas ali datum-čas, vrne ustrezno serijsko število datum/čas.

### WEBSERVICE

Vrne spletno vsebino z naslova URI.

### FILTERXML

Uporabi izraz XPath na dokumentu XML.

### ENCODEURL

Vrne v zapis URL kodiran niz.

## BAHTTEXT

Pretvori številko v besedilo v tajščini, vključno s tajskimi nazivi valute.

#### Skladnja

BAHTTEXT(število)

Število je poljubno število. »Baht« se doda k celemu delu števila, »Satang« pa k decimalnemu delu števila.

#### Primer

=BAHTTEXT(12,65) vrne niz tajskih znakov s pomenom »Dvanajst Baht in petinšestdeset Satang«.

#### Tehnični podatki

Ta funkcija ni del standarda Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format. Imenski prostor je

COM.MICROSOFT.BAHTTEXT

## BASE

Pretvori pozitivno celo število v besedilo številskega sistema na določeni osnovi. Uporabljajo se števila od 0-9 in črke od A-Z.

#### Skladnja

BASE(število; koren [; najmanjša_dolžina])

Število je pozitivno celo število, ki bo pretvorjeno.

Koren predstavlja osnovo številskega sistema. To je lahko poljubno pozitivno celo število med 2 in 36.

Najmanjša_dolžina (neobvezno) določi najmanjšo dolžino niza znakov, ki je bil ustvarjen. Če je besedilo krajše od določene dolžine, bodo levo od niza dodane ničle.

#### Primer

=BASE(17;10;4) vrne 0017 v desetiškem sistemu.

=BASE(17;2) vrne 10001 v dvojiškem sistemu.

=BASE(255;16;4) vrne 00FF v šestnajstiškem sistemu.

#### Oglejte si tudi ...

DECIMAL

## CHAR

Pretvori število v znak po veljavni kodni tabeli. Število je lahko dvomestno ali trimestno celo število.

Kode, večje od 127, so lahko odvisne od sistemske kodne tabele znakov (npr. iso-8859-1, iso-8859-2, Windows-1252, Windows-1250), zato morda niso prenosljive.

#### Skladnja

CHAR(število)

Število je število med 1 in 255 ter predstavlja kodno vrednost znaka.

#### Primer

=CHAR(100) vrne znak d.

="abc" & CHAR(10) & "def" v niz vstavi znak za novo vrstico.

## CLEAN

Odstrani vse nenatisljive znake iz niza.

#### Skladnja

CLEAN("besedilo")

Besedilo je besedilo, iz katerega bodo odstranjeni nenatisljivi znaki.

#### Primer

=LEN(CLEAN(CHAR(7) & "LibreOffice Calc" & CHAR(8))) vrne 16, kar kaže, da funkcija CLEAN odstrani nenatisljiva znaka Unicode U+0007 ("BEL") in U+0008 ("BS") na začetku in na koncu podanega znakovnega niza. CLEAN ne odstrani presledkov.

## CODE

Vrne številčno kodo prvega znaka v nizu besedila.

#### Skladnja

CODE("besedilo")

Besedilo je besedilo, za katerega je potrebno poiskati kodo za prvi znak.

Kode, večje od 127, so lahko odvisne od sistemske kodne tabele znakov (npr. iso-8859-1, iso-8859-2, Windows-1252, Windows-1250), zato morda niso prenosljive.

#### Primer

=CODE("Hoče") vrne 72, =CODE("hruška") vrne 104.

Tu uporabljena koda se ne nanaša na ASCII, temveč na trenutno naloženo kodno tabelo.

## CONCATENATE

Združi več besedilnih nizov v enega.

#### Skladnja

CONCATENATE(niz 1 [; niz 2 [; ... [; niz 255]]])

Niz 1[; niz 2][; ... ;[niz 255]] so nizi ali sklici na celice, ki vsebujejo nize.

#### Primer

=CONCATENATE("Dobro ";"jutro ";"gospa ";"Novak") vrne: Dobro jutro gospa Novak.

## DECIMAL

Pretvori besedilo, ki predstavlja niz v izbranem številskem sistemu v pozitivno celo število na določeni osnovi. Vrednost korena mora biti med 2 in 36. Presledki in tabulatorji se ne upoštevajo. Polje Besedilo ne loči malih in velikih črk.

Če je vrednost korena 16, se vodilni x ali X ali 0x ali 0X in dodan h ali H ne upoštevajo. Če je vrednost korena 2, se dodan b ali B ne upoštevata. Drugi znaki, ki ne sodijo v številski sistem, povzročijo napako.

#### Skladnja

DECIMAL("besedilo"; koren)

Besedilo je besedilo, ki bo pretvorjeno.

Koren predstavlja osnovo številskega sistema. To je lahko poljubno pozitivno celo število med 2 in 36.

#### Primer

=DECIMAL("17";10) vrne 17.

=DECIMAL("FACE";16) vrne 64206.

=DECIMAL("0101";2) vrne 5.

#### Oglejte si tudi ...

BASE

## DOLLAR

Pretvori število v količino v zapisu valute, zaokroženem na navedeno število decimalnih mest z uporabo decimalnega ločila, ki ustreza trenutnim krajevnim nastavitvam. V polje Vrednost vpišite število, ki ga hočete pretvoriti v valuto. Če želite, lahko v polje Decimalke vnesete število decimalnih mest. Če ne boste določili količine decimalnih mest, bodo vsa števila v obliki valute prikazana z dvema decimalnima mestoma.

Obliko valute si lahko nastavite v sistemskih nastavitvah.

#### Skladnja

DOLLAR(vrednost [; decimalke])

Vrednost je število, sklic na celico, ki vsebuje število, ali formula, ki vrne število.

Decimalke je neobvezen parameter števila decimalnih mest.

#### Primer

=DOLLAR(255) vrne $255.00 pri angleških (ZDA) krajevnih nastavitvah in valuti USD (dolar), ￥255.00 pri japonskih krajevnih nastavitvah in valuti JPY (jen) oz. 255,00 € pri slovenskih krajevnih nastavitvah in valuti EUR (evro).

=DOLLAR(367,456;2) vrne 367,46 $.

## EXACT

Primerja dva niza besedil in vrne TRUE, če sta enaka. Ta funkcija loči med malimi in velikimi črkami.

#### Skladnja

EXACT("besedilo1"; "besedilo2")

Besedilo1 je prvo besedilo za primerjavo.

Besedilo2 je drugo besedilo za primerjavo.

#### Primer

=EXACT("Društvo Lugos";"Društvo LUGOS") vrne FALSE.

## FIND

Poišče položaj niza besedila v drugem nizu. Lahko tudi definirate, kje naj se iskanje začne. Iskani niz je lahko število ali kakršen koli niz znakov. Funkcija iskanja loči med malimi in velikimi črkami.

#### Skladnja

SEARCH("najdi_besedilo"; "besedilo" [; položaj])

Najdi_besedilo se nanaša na besedilo, ki ga želite najti.

Besedilo je besedilo, v katerem poteka iskanje.

Položaj (neobvezno) je položaj v besedilu, od katerega naprej poteka iskanje.

#### Primer

=FIND(76;998877665544) vrne 6.

## FIXED

Vrne število kot besedilo z navedenim številom decimalnih mest in opcijsko z ločilom tisočic.

#### Skladnja

FIXED(število; [decimalke = 2 [; brez_ločila_tisočic = FALSE]])

Število se zaokroži na decimalke decimalnih mest (za decimalnim ločilom) in rezultat je oblikovan kot besedilo, skladno z ustreznimi področnimi nastavitvami.

Decimalke (neobvezno) določa število prikazanih decimalnih mest. Če je parameter decimalke negativen, bo število zaokroženo na ABS(decimake) mest desno od decimalne vejice. Če je decimalke ulomek, bo preprosto okrajšan in ne upošteva najbližjega celega števila.

Brez_ločila_tisočic (neobvezno) določa, ali bo uporabljeno ločilo tisočic. Če je parameter TRUE ali število, ki ni enako nič, ločilo tisočic v izdelanem nizu ne bo uporabljeno. Če je parameter enak 0 ali pa ga sploh ni, bodo prikazana ločila tisočic, kot to določajo vaše veljavne področne nastavitve.

#### Primer

=FIXED(1234567,89;3) vrne 1.234.567,890 kot besedilni niz.

=FIXED(123456,789;;TRUE) vrne 123456,79 kot besedilni niz.

=FIXED(12345,6789;-2) vrne 12.300 kot besedilni niz.

=FIXED(12134567,89;-3;1) vrne 12135000 kot besedilni niz.

=FIXED(12345,789;3/4) vrne 12.346 kot besedilni niz.

=FIXED(12345,789;8/5) vrne 12.345,8 kot besedilni niz.

## LEFT

Vrne prvi znak ali znake besedila.

#### Skladnja

LEFT("besedilo" [; število])

Besedilo je besedilo, v katerem želite določiti začetne dele besed.

Število (neobvezno) določi število znakov za začetno besedilo. Če tega parametra ne določite, je vrnjen en znak.

#### Primer

=LEFT("sladoled";3) vrne »sla«.

## LEFTB

Vrne prvi znak ali znake besedila DBCS.

Ta funkcija je na voljo od LibreOffice 4.2.

#### Skladnja

LEFT("besedilo" [; število_bajtov])

Besedilo je besedilo, v katerem želite določiti začetne dele besed.

Število_bajtov (neobvezno) določi število znakov, ki jih želite izluščiti z začetka s funkcijo LEFTB, glede na bajte. Če tega parametra ne določite, vrne en znak.

#### Primer

=LEFTB("中国";1) vrne » « (1 bajt je le pol znaka DBCS, zato funkcija vrne znak za presledek).

=LEFTB("中国";2) vrne »中« (2 bajta tvorita celovit znak DBCS).

=LEFTB("中国";3) vrne »中 « (3 bajti tvorijo en znak DBCS in pol, zato je zadnji vrnjeni znak presledek).

=LEFTB("中国";4) vrne »中国« (4 bajti tvorijo dva celovita znaka DBCS).

=LEFTB("pisarna";3) vrne »pis« (3 znaki, ki niso znaki DBCS, vsak dolžine 1 bajt).

## LEN

Izračuna dolžino niza skupaj s presledki.

#### Skladnja

LEN("besedilo")

Besedilo je besedilo, katerega dolžino želite določiti.

#### Primer

=LEN("Dober večer") vrne 11.

=LEN(12345,67) vrne 8.

## LENB

Za jezike z naborom dvobajtnih znakov (DBCS) vrne število bajtov za predstavljanje znakov v nizu besedila.

Ta funkcija je na voljo od LibreOffice 4.2.

#### Skladnja

LENB("besedilo")

Besedilo je besedilo, katerega dolžino želite določiti.

#### Primer

LENB("中") vrne 2 (1 znak DBCS, ki ga tvorita 2 bajta).

LENB("中国") vrne 4 (2 znaka DBCS, vsakega tvorita 2 bajta).

LENB("pisarna") vrne 7 (7 znakov, ki niso znaki DBCS, vsakega tvori 1 bajt).

=LENB("Dober večer") vrne 11.

=LENB(12345,67) vrne 8.

## LOWER

Vse velike črke v besedilnem nizu pretvori v male.

#### Skladnja

LOWER("besedilo")

Besedilo se nanaša na besedilo, ki bo pretvorjeno.

#### Primer

=LOWER("Lugos") vrne lugos.

## MID

Vrne niz besedila. Parametra določata začetni položaj in število znakov.

#### Skladnja

MID("besedilo"; začetek; število)

Besedilo je besedilo, iz katerega se bodo izločali posamezni deli.

Začetek je položaj znaka, od katerega naprej se bodo izločali deli besedila.

Število določa število znakov v delu besedila.

#### Primer

=MID("LUGOS";3;2) vrne GO.

## MIDB

Vrne niz besedila v naboru dvobajtnih znakov (DBCS). Parametra določata začetni položaj in število znakov.

Ta funkcija je na voljo od LibreOffice 4.2.

#### Skladnja

MIDB("besedilo"; začetek; število_bajtov)

Besedilo je besedilo, iz katerega se bodo izločali posamezni deli.

Začetek je položaj znaka, od katerega naprej se bodo izločali deli besedila.

Število_bajtov določa vrnjeno število znakov iz besedila dvobajtnih znakov (DBCS), v bajtih.

#### Primer

=MIDB("中国";1;0) vrne »« (0 bajtov je vedno prazen niz).

=MIDB("中国";1;1) vrne » « (1 bajt predstavlja le polovico znaka DBCS, zato je rezultat znak za presledek).

=MIDB("中国";1;2) vrne »中« (2 bajta tvorita en celovit znak DBCS).

=MIDB("中国";1;3) vrne »中 « (3 bajti tvorijo en znak DBCS in pol, zato zadnji bajt vrne presledek).

=MIDB("中国";1;4) vrne »中国« (4 bajti tvorijo dva celovita znaka DBCS).

=MIDB("中国";2;1) vrne » « (bajt na položaju 2 ni na začetku znaka v nizu DBCS; vrnjen je 1 znak za presledek).

=MIDB("中国";2;2) vrne » « (bajt na položaju 2 kaže na drugo polovico prvega znaka v nizu DBCS; iskana 2 bajta zato tvorita drugo polovico prvega znaka in prvo polovico drugega znaka v nizu; zato funkcija vrne 2 znaka za presledek).

=MIDB("中国";2;3) vrne » 国« (bajt na položaju 2 ni na začetku znaka v nizu DBCS; za bajt na položaju 2 vrne znak za presledek).

=MIDB("中国";3;1) vrne » « (bajt na položaju 3 je na začetku znaka v nizu DBCS, toda 1 bajt dolžine je le pol znaka DBCS, zato vrne znak za presledek).

=MIDB("中国";3;2) vrne »国« (bajt na položaju 3 je na začetku znaka v nizu DBCS; 2 bajta tvorita en znak DBCS).

=MIDB("pisarna";2;3) vrne »isa« (bajt na položaju 2 je na začetku znaka v nizu, ki ni niz DBCS, tako 3 bajti takšnega niza tvorijo 3 znake).

## PROPER

Vse besede v nizu besedila napiše z veliko začetnico.

#### Skladnja

PROPER("besedilo")

Besedilo se nanaša na besedilo, ki bo pretvorjeno.

#### Primer

=PROPER("društvo lugos") vrne Društvo Lugos.

## REPLACE

Zamenja znake v nizu besedila z drugim nizom besedila. To funkcijo se lahko uporabi tako za zamenjavo črk kot tudi števil (ki se avtomatsko pretvorijo v besedilo). Rezultat te funkcije je vedno prikazan kot besedilo. Če hočete s številom, ki ga je že nadomestilo besedilo, delati nadaljnje izračune, ga morate spremeniti nazaj v število s funkcijoVALUE.

Če nočete, da program število prepozna kot število in ga avtomatično pretvori v besedilo, ga dajte v narekovaje.

#### Skladnja

REPLACE("besedilo"; položaj; dolžina; "novo_besedilo")

Besedilo se nanaša na besedilo, v katerem bo zamenjan določen del.

Položaj je položaj znaka, kjer se bo začela zamenjava besedila.

Dolžina je število znakov v besedilu, ki bodo zamenjani.

Novo_besedilo je besedilo, ki bo nadomestilo Besedilo.

#### Primer

=REPLACE("1234567";1;1;"444") vrne »444234567«. En znak na položaju 1 je v celoti zamenjalo novo_besedilo.

## REPT

Niz znakov ponovi v želenem številu kopij.

#### Skladnja

REPT("besedilo"; število)

Besedilo je besedilo, ki bo ponovljeno.

Število je število ponovitev.

#### Primer

=REPT("Dobro jutro";2) vrne Dobro jutroDobro jutro.

Za podrobnosti o tej funkciji glejte stran wiki o funkciji REPT (v angl.).

## RIGHT

Vrne zadnji znak ali znake besedila.

#### Skladnja

RIGHT("besedilo" [; število])

Besedilo je besedilo, v katerem bo določen končni del.

Število (neobvezno) je število znakov od desnega konca besedila. Če tega parametra ne določite, funkcija vrne en znak.

#### Primer

=RIGHT("LUGOS";3) vrne GOS.

## RIGHTB

Vrne zadnji znak ali znake besedila v naboru dvobajtnih znakov (DBCS).

Ta funkcija je na voljo od LibreOffice 4.2.

#### Skladnja

RIGHTB("besedilo" [; število_bajtov])

Besedilo je besedilo, v katerem bo določen končni del.

Število_bajtov (neobvezno) določi število znakov, ki jih želite izluščiti s funkcijo RIGHTB, glede na bajte. Če tega parametra ne določite, vrne en bajt.

#### Primer

RIGHTB("中国";1) vrne » « (1 bajt je le pol znaka DBCS. zato vrne znak za presledek).

RIGHTB("中国";2) vrne »国« (2 bajta tvorita en celovit znak DBCS).

RIGHTB("中国";3) vrne » 国« (3 bajti tvorijo pol znaka DBCS in en celovit znak DBCS, zato za prvo polovico znaka vrne presledek).

RIGHTB("中国";4) vrne »中国« (4 bajti tvorijo dva celovita znaka DBCS).

RIGHTB("pisarna";3) vrne »rna« (3 znaki, ki niso znaki DBCS, vsakega tvori 1 bajt).

## SEARCH

Izračuna položaj dela besedila v nizu znakov. Lahko si nastavite točko v besedilu, pri kateri naj se iskanje začne. Besedilo, po katerem boste iskali, je lahko število ali kakršen koli niz znakov. Funkcija iskanja ne loči med malimi in velikimi črkami. Če besedila ne najde, vrne napako 519 (#VALUE).

Iskanje podpira regularne izraze. Če so ti omogočeni, lahko vnesete npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi regularen izraz, morate pred vsak meta-znak regularnega izraza ali operator vnesi znak »\« ali pa besedilo zaobjeti v \Q...\E. Samodejno vrednotenje nadomestnih znakov ali regularnega izraza lahko vklopite in izklopite v LibreOffice – Nastavitve Orodja – Možnosti – LibreOffice Calc – Izračuni.

Če uporabljate funkcije, v katerih je vsaj eden argument iskalni pogoj, ki predstavlja regularni izraz, se bo niz pogojev najprej poskusil pretvoriti v števila. Primer: ».0« se pretvori v 0.0 itn. Če pretvorba uspe, iskanje ne bo vrnilo regularnega izraza, temveč število. Če preklopite na slovenske krajevne nastavitve, kjer decimalno ločilo ni pika, temveč vejica, pa pretvorba regularnega izraza deluje. Če želite vsiliti iskanje regularnega izraza namesto števila, uporabite izraz, ki ga ni mogoče pretvoriti v numeričnega, npr. ».[0]«, ».\0« ali »(?i).0«.

#### Skladnja

SEARCH("najdi_besedilo"; "besedilo" [; položaj])

Najdi_besedilo je besedilo, ki ga želite poiskati.

Besedilo je besedilo, v katerem bo potekalo iskanje.

položaj (neobvezno) je položaj v besedilu, od katerega naprej naj poteka iskanje.

#### Primer

=SEARCH(54;998877665544) vrne 10.

## SUBSTITUTE

V nizu nadomesti del starega besedila z novim.

#### Skladnja

SUBSTITUTE("besedilo"; "najdi_besedilo"; "novo_besedilo" [; pojavitev])

Besedilo je besedilo, v katerem bodo zamenjani določeni deli.

Najdi_besedilo je del besedila, ki bo (nekajkrat) zamenjan.

Novo_besedilo je besedilo, ki bo nadomestilo del starega.

Pojavitev (neobvezno) nakazuje, katera pojavitev iskanega besedila naj se zamenja. Če ta parameter ni podan, se iskano besedilo zamenja povsod.

#### Primer

=SUBSTITUTE("123123123";"3";"abc") vrne 12abc12abc12abc.

=SUBSTITUTE("123123123";"3";"abc";2) vrne 12312abc123.

## T

Ta funkcija vrne ciljno besedilo ali prazen niz, če cilj ni besedilo.

#### Skladnja

T(vrednost)

Če je vrednost niz ali se sklicuje na niz, T vrne ta niz besedila, sicer vrne prazen niz.

#### Primer

=T(12345) vrne prazen niz.

=T("12345") vrne niz 12345.

## TEXT

Vrednost spremeni v besedilo glede na dano obliko.

#### Skladnja

TEXT(vrednost; oblika)

Vrednost je (numerična ali besedilna) vrednost, ki bo pretvorjena.

Oblika je besedilo, ki določa obliko. Uporabljajte takšna ločila za desetice in tisočice, kot veljajo za jezik, ki je nastavljen pri obliki celic.

#### Primer

=TEXT(12,34567;"###,##") vrne besedilo 12,35

=TEXT(12,34567;"000,00") vrne besedilo 012,35

=TEXT("xyz";"=== @ ===") vrne besedilo === xyz ===

Glejte tudi Kode za obliko številk: uporabniško določene kode za obliko številk po meri.

## TRIM

Odstrani presledke iz niza, tako da pusti le en presledek med posameznimi besedami.

#### Skladnja

TRIM("besedilo")

Besedilo se nanaša na besedilo, v katerem želite odstraniti presledke.

#### Primer

=TRIM(" pozdravljen, svet ") vrne pozdravljen, svet brez začetnih in končnih presledkov in z enojnim presledkom med besedami.

## UNICHAR

Pretvori številčno kodo v znak ali črko Unicode.

#### Skladnja

UNICHAR(število)

#### Primer

=UNICHAR(169) vrne znak zaščitenih avtorskih pravic ©.

Glejte tudi funkcijo UNICODE().

## UNICODE

Vrne številčno kodo prvega znaka Unicode v nizu besedila.

#### Skladnja

UNICODE("besedilo")

#### Primer

=UNICODE("©") številko znaka Unicode 169 za znak zaščitenih avtorskih pravic.

Glejte tudi funkcijo UNICHAR().

## UPPER

Izbran niz črk v besedilnem polju spremeni v velike črke.

#### Skladnja

UPPER("besedilo")

Besedilo se nanaša na male črke, ki jih želite spremeniti v velike.

#### Primer

=UPPER("Dober večer") vrne DOBER VEČER.

Podobne teme

Seznam funkcij po kategorijah